project('EMPER', 'c', 'cpp',
		version: '0.0.1-alpha1-SNAPSHOT',
		default_options : [
		  'warning_level=3',
		  'c_std=gnu11',
		  'cpp_std=c++17',
		  'b_ndebug=if-release',
		  'werror=true',
		])

# TODO: Re-enable that warning.
add_project_arguments('-Wno-non-virtual-dtor', language: 'cpp')

thread_dep = dependency('threads')
emper_dependencies = [thread_dep]

run_target('iwyu',
		   command: 'tools/check-iwyu')

conf_data = configuration_data()
option_urcu = get_option('userspace-rcu')
conf_data.set('EMPER_LIBURCU', option_urcu)
if option_urcu
	liburcu_dep = dependency('liburcu')
	emper_dependencies += [liburcu_dep]
endif

conf_data.set('EMPER_WORKER_SLEEP', get_option('worker_sleep'))
conf_data.set('EMPER_LOCKED_WS_QUEUE', get_option('locked_ws_queue'))
conf_data.set('EMPER_OVERFLOW_QUEUE', get_option('overflow_queue'))
conf_data.set('EMPER_LOCKED_MPSC_QUEUE', get_option('locked_mpsc_queue'))
conf_data.set('EMPER_STATS', get_option('stats'))

subdir('emper')
subdir('tests')
subdir('apps')
subdir('eval')
subdir('doc')