Powerset.hs

{-# LANGUAGE DeriveFunctor #-}
{-# LANGUAGE InstanceSigs #-}
{-# LANGUAGE TypeFamilies #-}
{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE TupleSections #-}

module Data.Functors.Powerset (Powerset(..), powerset, Powerset') where

import           Data.Vector (Vector)
import qualified Data.Vector as V
import qualified Data.Yaml as Yaml

import           Data.RefinementInterface
import qualified Data.MorphismEncoding as Encoding
import           Text.Parser.Functor
import           Text.Parser.FunctorNew
import qualified Text.Parser.Lexer as L

-- New interface

data Powerset' a = Powerset' a
  deriving (Functor)

instance ParseFunctor Powerset' where
  precedence = 5
  parseFunctor = Prefix' (L.symbol "P" >> pure Powerset')

-- Old interface

data Powerset = Powerset
  deriving (Show)

powerset :: FunctorParser Powerset
powerset = Prefix (L.symbol "P" >> pure Powerset)

instance RefinementInterface Powerset where
  -- | No edge labels
  type Label Powerset = ()
  -- | Tuple of (|edgesToC\S|, |edgesToS|)
  type Weight Powerset = (Int, Int)
  -- | Does this state have at least one successor?
  type H1 Powerset = Bool
  -- | Tuple of:
  --    - do we have edges to the rest?
  --    - do we have edges to C\S?
  --    - do we have edges to S?
  type H3 Powerset = (Bool, Bool, Bool)

  parse _ arr = do
    successors <- V.imapM parseNode arr

    let structure = V.map (not . V.null . snd) successors
        edges = V.concatMap (\(from, succs) -> fmap (Encoding.Edge from ()) succs) successors

    return $ Encoding.new structure edges

    where
      parseNode :: Int -> Yaml.Value -> Yaml.Parser (Int, Vector Int)
      parseNode nodeIdx value = (nodeIdx,) <$> Yaml.parseJSON value

  init :: H1 Powerset -> [Label Powerset] -> Weight Powerset
  init _ = (0, ) . length

  update :: [Label Powerset] -> Weight Powerset
         -> (Weight Powerset, H3 Powerset, Weight Powerset)
  update labels (toRest, toC) =
    let
      toS = length labels
      toCwithoutS = toC - toS
      weightToS = (toRest + toCwithoutS, toS)
      h3 = (toRest > 0, toCwithoutS > 0, toS > 0)
      weightToCwithoutS = (toRest + toS, toCwithoutS)
    in
      (weightToS, h3, weightToCwithoutS)