Skip to content
Snippets Groups Projects
Select Git revision
  • 6a25a3885a8b198336a01bf496598b67aa984123
  • master default protected
  • android-7.1.2_r28_klist
  • pie-cts-release
  • pie-vts-release
  • pie-cts-dev
  • oreo-mr1-iot-release
  • sdk-release
  • oreo-m6-s4-release
  • oreo-m4-s12-release
  • pie-release
  • pie-r2-release
  • pie-r2-s1-release
  • oreo-vts-release
  • oreo-cts-release
  • oreo-dev
  • oreo-mr1-dev
  • pie-gsi
  • pie-platform-release
  • pie-dev
  • oreo-cts-dev
  • android-o-mr1-iot-release-1.0.4
  • android-9.0.0_r8
  • android-9.0.0_r7
  • android-9.0.0_r6
  • android-9.0.0_r5
  • android-8.1.0_r46
  • android-8.1.0_r45
  • android-n-iot-release-smart-display-r2
  • android-vts-8.1_r5
  • android-cts-8.1_r8
  • android-cts-8.0_r12
  • android-cts-7.1_r20
  • android-cts-7.0_r24
  • android-o-mr1-iot-release-1.0.3
  • android-cts-9.0_r1
  • android-8.1.0_r43
  • android-8.1.0_r42
  • android-n-iot-release-smart-display
  • android-p-preview-5
  • android-9.0.0_r3
41 results

net.te

Blame
    • Alex Klyubin's avatar
      372dc67f
      Move netdomain policy to private · 372dc67f
      Alex Klyubin authored
      This leaves only the existence of netdomain attribute as public API.
      All other rules are implementation details of this attribute's policy
      and are thus now private.
      
      Test: No change to policy according to sesearch, except for
            disappearance of all allow rules to do with netdomain_current
            and *_current attributes targeted when netdomain rules reference
            public types.
      Bug: 31364497
      Change-Id: I102e649374681ce1dd9e1e5ccbaaa5cb754e00a0
      372dc67f
      History
      Move netdomain policy to private
      Alex Klyubin authored
      This leaves only the existence of netdomain attribute as public API.
      All other rules are implementation details of this attribute's policy
      and are thus now private.
      
      Test: No change to policy according to sesearch, except for
            disappearance of all allow rules to do with netdomain_current
            and *_current attributes targeted when netdomain rules reference
            public types.
      Bug: 31364497
      Change-Id: I102e649374681ce1dd9e1e5ccbaaa5cb754e00a0
    mls_macros 1.22 KiB
    ########################################
    #
    # gen_cats(N)
    #
    # declares categores c0 to c(N-1)
    #
    define(`decl_cats',`dnl
    category c$1;
    ifelse(`$1',`$2',,`decl_cats(incr($1),$2)')dnl
    ')
    
    define(`gen_cats',`decl_cats(0,decr($1))')
    
    ########################################
    #
    # gen_sens(N)
    #
    # declares sensitivites s0 to s(N-1) with dominance
    # in increasing numeric order with s0 lowest, s(N-1) highest
    #
    define(`decl_sens',`dnl
    sensitivity s$1;
    ifelse(`$1',`$2',,`decl_sens(incr($1),$2)')dnl
    ')
    
    define(`gen_dominance',`s$1 ifelse(`$1',`$2',,`gen_dominance(incr($1),$2)')')
    
    define(`gen_sens',`
    # Each sensitivity has a name and zero or more aliases.
    decl_sens(0,decr($1))
    
    # Define the ordering of the sensitivity levels (least to greatest)
    dominance { gen_dominance(0,decr($1)) }
    ')
    
    ########################################
    #
    # gen_levels(N,M)
    #
    # levels from s0 to (N-1) with categories c0 to (M-1)
    #
    define(`decl_levels',`dnl
    level s$1:c0.c$3;
    ifelse(`$1',`$2',,`decl_levels(incr($1),$2,$3)')dnl
    ')
    
    define(`gen_levels',`decl_levels(0,decr($1),decr($2))')
    
    ########################################
    #
    # Basic level names for system low and high
    #
    define(`mls_systemlow',`s0')
    define(`mls_systemhigh',`s`'decr(mls_num_sens):c0.c`'decr(mls_num_cats)')